home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / a_utils / perl / msds-prl / ptchds19.zoo / moredos_asm < prev    next >
Text File  |  1992-02-23  |  7KB  |  253 lines
  1. MS-DOS patches to perl.
  2. Apply this patch to the standard perl source, version 4, patch level 19,
  3. using "patch -p."  Do this in the root directory of the perl source
  4. distribution.
  5.  
  6. You can cat all these patches together and pipe the output to patch -p.
  7.  
  8. Len Reed
  9. Holos Software, Inc.
  10. ..!gatech!holos0!lbr
  11. holos0!lbr@gatech.edu
  12. --------------------------------------
  13. *** msdos/moredos.asm.old    Sun Feb 23 08:48:16 1992
  14. --- msdos/moredos.asm    Thu Nov 14 08:56:36 1991
  15. ***************
  16. *** 0 ****
  17. --- 1,235 ----
  18. + ; Various stuff that has to be in assembly langauge because the
  19. + ; C library under DOS won't do what we need.
  20. + 
  21. + 
  22. + ; Copyright (c) 1990 Leonard Reed.
  23. + ; Author: ...!gatech!holos0!lbr
  24. + 
  25. + ; This program is free software; you can redistribute it and/or
  26. + ; modify it under the terms of the GNU General Public License
  27. + ; (version 1), as published by the Free Software Foundation, and
  28. + ; found in the file 'LICENSE' included with this distribution.
  29. + 
  30. + ; This program is distributed in the hope that it will be useful,
  31. + ; but WITHOUT ANY WARRANTY; without even the implied warrant of
  32. + ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  33. + ; GNU General Public License for more details.
  34. + 
  35. + ; You must assemble this file with masm flag
  36. + ;    -dmmodel where model is one of {small, compact, medium, large}
  37. + ;
  38. + ifdef msmall
  39. +         .model    small
  40. +   ARG    equ    4
  41. + endif
  42. + ifdef mcompact
  43. +     .model  compact
  44. +   ARG    equ    4
  45. + endif
  46. + ifdef mmedium
  47. +     .model    medium
  48. +   ARG    equ    6
  49. + endif
  50. + ifdef mlarge
  51. +     .model    large
  52. +   ARG    equ    6
  53. + endif
  54. + .data
  55. + 
  56. +     extrn __psp:word        ; our PSP, set by C library startup code
  57. +     extrn _errno:word        ; C library Unix-like error code
  58. +     extrn __osversion:word    ; MS-DOS version, set by C library startup
  59. + 
  60. + SFT_block    Struc        ; header for s system file table block
  61. + d_next        dd    ?    ; pointer to next block, or ????:ffffh for end
  62. + d_count        dw    ?    ; num of system file table entries in this block
  63. + SFT_block    Ends
  64. + 
  65. + .code
  66. + 
  67. + ; struct sft far * dos_sys_file(int handle);
  68. + 
  69. + ; Return a pointer to the system file table entry for a given file handle.
  70. + ; This routine returns zero for success and NULL (with errno set) for failure.
  71. + ; We resolve the file handle to a system file table entry and
  72. + ; change the value there.  This requires knowledge of DOS's internals
  73. + ; that is widely know but not "documented" by Microsoft.
  74. + ; Refer to _The Waite Group's MS-DOS Developer's Guide_, 2nd edition,
  75. + ; Howard Sams & Co., pp. 210-217.
  76. + 
  77. +     Public _dos_sys_file
  78. + _dos_sys_file Proc
  79. +     push bp
  80. +     mov bp,sp
  81. +     push di
  82. + 
  83. +     mov es,__psp    ; our program segment prefix
  84. +     mov ax,es:[32h]    ; size of our job file table (max num of handles)
  85. + 
  86. +     mov bx,[bp+ARG]    ; get the file handle passed to this routine
  87. + 
  88. +     cmp bx,ax
  89. +     jae bad_handle    ; bad handle, possibly 0ffffh from failed open()
  90. + 
  91. +     les di,es:[34h]    ; address of the job file table (typically just es:18h)
  92. +     mov bl,es:[bx+di]    ; get system file table entry for this handle
  93. +     cmp bl,0ffh        ; is the entry used?
  94. +     je bad_handle
  95. + 
  96. +     mov dl,bl        ; save the system file table entry momentarily in DX
  97. +     sub dh,dh
  98. + 
  99. +     mov ah,52h        ; "undocumented" call to get ptr to list of lists
  100. +     int 21h        ; pointer returned in ES:BX
  101. + 
  102. +     les di,es:[bx+4]    ; get pointer to first SFT_block
  103. +     mov ax,dx        ; index of entry sought
  104. + 
  105. + ; Now have ES:DI ==> first SFT_BLOCK
  106. + ;       AL == AX == system file table number for the given handle
  107. + 
  108. +     sub bx,bx
  109. + 
  110. + new_block:
  111. +     add bx,es:[di].d_count    ; set BX to first sys file number in next block
  112. +     cmp ax,bx            ; is the sought number in this block?
  113. +     jl found_it
  114. +     
  115. +     cmp di,0ffffh        ; at end of chain ?
  116. +     je bad_handle        ; didn't find it: really is worse than EBADF!
  117. +     les di,es:[di].d_next    ; pointer to next block
  118. +     jmp new_block
  119. + 
  120. + found_it:
  121. +     sub bx,es:[di].d_count    ; sys file number of 1st SFN this block
  122. +     sub ax,bx            ; offset of sought sys file number's entry
  123. +     mov bx,__osversion        ; test DOS version
  124. +     cmp bl,4
  125. +     mov bl,3bh            ; assume 4.x/5.x structure size
  126. +     jae its_dos_4
  127. +     mov bl,35h            ; before 4.0, structures were smaller
  128. + 
  129. + its_dos_4:
  130. +     mul bl            ; set AX to offset (almost) into block
  131. +     add ax,size SFT_block    ; add the header size
  132. +     add ax,di            ; add the offset of the block
  133. +     mov dx,es            ; now DX:AX points to the sought entry
  134. +     jmp short get_out
  135. + 
  136. + bad_handle:
  137. +     mov _errno,9    ; EBADF
  138. +     sub ax,ax
  139. +     mov dx,ax
  140. + 
  141. + get_out:
  142. +     pop di
  143. +     pop bp
  144. +     ret
  145. + _dos_sys_file Endp
  146. + 
  147. + ; Routine to return maximum number of files, similar to Unix NOFILE.
  148. + ; Ususally under dos this is 20, but it can be changed.
  149. + 
  150. + ; int dos_get_nofiles(void);
  151. + 
  152. +     Public _dos_get_nofiles
  153. + _dos_get_nofiles Proc
  154. +     mov es,__psp    ; our program segment prefix
  155. +     mov ax,es:[32h]    ; size of our job file table (max num of handles)
  156. +     ret
  157. + _dos_get_nofiles Endp
  158. + 
  159. + ; Routine to return pointer to the file table that maps handles
  160. + ; to system files.  Usually in PSP at offset 18h, but can be remapped.
  161. + 
  162. + ; unsigned char far * dos_get_sft_map(void);
  163. + 
  164. +     Public _dos_get_sft_map
  165. + _dos_get_sft_map Proc
  166. +     mov es,__psp    ; our program segment prefix
  167. +     les ax,es:[34h]    ; address of the job file table (typically just es:18h)
  168. +     mov dx,es        ; return pointer in DX:AX
  169. +     ret
  170. + _dos_get_sft_map Endp
  171. + 
  172. + ; Duplicate a handle bypassing the C library
  173. + ; Used by spawn logic to control inheritance without confusing the
  174. + ; C library about O_BINARY/O_TEXT, I/O modes, etc.
  175. + 
  176. + ; int dos_dup(int);
  177. + 
  178. +     Public _dos_dup
  179. + _dos_dup Proc
  180. +     push bp
  181. +     mov bp,sp
  182. + 
  183. +     mov bx,[bp+ARG]
  184. +     mov ah,45h
  185. +     int 21h
  186. +     jc dup_failure
  187. + 
  188. +     pop bp
  189. +     ret
  190. + 
  191. + dup_failure:        ; also jumped to from _dos_dup2
  192. +     cmp ax,6h        ; Is DOS trying to say EBADF (bad handle?)
  193. +     je dup_bad_handle
  194. +     mov ax,24        ; assume EMFILE, out of files or handles
  195. +     jmp short dup_error_exit
  196. + 
  197. + dup_bad_handle:
  198. +     mov ax,9    ; EBADF, bad file handle
  199. + 
  200. + dup_error_exit:
  201. +     mov _errno,ax
  202. +     mov ax,-1
  203. +     pop bp
  204. +     ret
  205. + _dos_dup Endp
  206. + 
  207. + ; Duplicate a handle to a specific new handle, bypassing the C library.
  208. + ; Used by spawn logic to control inheritance without confusing the
  209. + ; C library about O_BINARY/O_TEXT, I/O modes, etc.
  210. + 
  211. + ; int dos_dup2(int current, int duplicate);
  212. + 
  213. +     Public _dos_dup2
  214. + _dos_dup2 Proc
  215. +     push bp
  216. +     mov bp,sp
  217. + 
  218. +     mov bx,[bp+ARG]
  219. +     mov cx,[bp+ARG+2]
  220. +     mov ah,46h
  221. +     int 21h
  222. +     jc dup_failure    ; see _dos_dup code
  223. + 
  224. +     pop bp
  225. +     ret
  226. + _dos_dup2 Endp
  227. + 
  228. + ; Close a handle without telling the C runtime library.
  229. + ; Used by spawn logic to control inheritance without confusing the
  230. + ; C library about O_BINARY/O_TEXT, I/O modes, etc.
  231. + 
  232. + ; int dos_close(int handle);
  233. + 
  234. +     Public _dos_close
  235. + _dos_close Proc
  236. +     push bp
  237. +     mov bp,sp
  238. + 
  239. +     mov bx,[bp+ARG]
  240. +     mov ah,3eh
  241. +     int 21h
  242. +     mov ax,0        ; no error (note this doesn't affect CF)
  243. +     jnc closed_it
  244. +     mov _errno,9    ; EBADF (this is a guess, we could inspect AX)
  245. +     mov ax,-1
  246. + 
  247. + closed_it:
  248. +     pop bp
  249. +     ret
  250. + _dos_close Endp
  251. + 
  252. +     End
  253.